Povzetek

3D-render of partially-transparent Rhombic dodecahedron (dual of cuboctahedron Archimedean solid).

From en:Image:Rhombic dodecahedron.jpg

Ta diagram je mogoče poustvariti z uporabo vektorske grafike kot SVG-datoteko. To ima več prednosti; več informacij je na razpolago na strani Commons:Media for cleanup. Če je SVG-oblika te datoteke že na razpolago, jo, prosimo, naložite. Potem, ko boste SVG naložili, to predlogo zamenjajte z izrazom {{vector version available|ime nove slike.svg}}.

Ta diagram slika je bila naložena v formatu JPEG, čeprav sestoji iz nefotografskih podatkov. Te informacije bi bile bolj učinkovito ali natančno shranjene v formatu PNG ali SVG. Če je mogoče, naložite različico PNG ali SVG te slike brez artefaktov stiskanja, izpeljanih iz ne-JPEG vira (ali z odstranjenimi obstoječimi artefakti). Ko boste to storili, označite JPEG različico z {{Superseded|NewImage.ext}} in to oznako odstranite.. Ta oznaka naj se ne uporablja za fotografije ali preslikave. Za več informacij glejte {{BadJPEG}}.

Licenca

Ta dokument je dovoljeno kopirati, razširjati in/ali spreminjati pod pogoji Licence GNU za prosto dokumentacijo, različica 1.2 ali katera koli poznejša, ki jo je objavila ustanova Free Software Foundation; brez nespremenljivih delov ter brez besedil na sprednji ali zadnji platnici. Kopija licence je vključena v razdelek Licenca GNU za prosto dokumentacijo.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

	Datoteka je objavljena pod licenco Creative Commons Priznanje avtorstva-Deljenje pod enakimi pogoji 3.0 Nedoločena.
	Dovoljeno vam je: deljenje – reproducirati, distribuirati in javno priobčevati delo predelava – predelati delo Pod naslednjimi pogoji: priznanje avtorstva – Navesti morate ustrezno avtorstvo, povezavo do licence in morebitne spremembe. To lahko storite na kakršen koli primeren način, vendar ne na način, ki bi nakazoval, da dajalec licence podpira vas ali vašo uporabo dela. deljenje pod enakimi pogoji – Če boste to vsebino predelali, preoblikovali ali uporabili kot izhodišče za drugo delo, morate svoj prispevek distribuirati pod enako ali združljivo licenco, kot jo ima izvirnik.
	Ta oznaka dovoljenja je bila datoteki dodana kot del posodobitve licence GFDL.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue

Povray code

The file was produced via the command "povray rhombic_dodecahedron.ini" on a Mac OS X machine with the fink installation of POV-Ray. The following three files are used. (GFDL applies to all)

File "rhombic_dodecahedron.povi"

#declare A=sqrt(2);
#declare R=0.025;

#declare rhombdod =
intersection {
    box { < -2, -2, -2>, <2,2,2> }
    plane { < 1, 1, 0>, A } 
    plane { < 1,-1, 0>, A }
    plane { <-1, 1, 0>, A }
    plane { <-1,-1, 0>, A }
    plane { < 1, 0, 1>, A }
    plane { < 1, 0,-1>, A }
    plane { <-1, 0, 1>, A }
    plane { <-1, 0,-1>, A }
    plane { < 0, 1, 1>, A }
    plane { < 0, 1,-1>, A }
    plane { < 0,-1, 1>, A }
    plane { < 0,-1,-1>, A }
    }

#declare tripod = 
    union{
        cylinder { <2,0,0>, <1,1,1>, R }
        cylinder { <0,2,0>, <1,1,1>, R }
        cylinder { <0,0,2>, <1,1,1>, R }
        sphere { <1,1,1>, R }
        }
#declare rhombdodedges =
    union {
        object { tripod }
        object { tripod rotate 90*z }
        object { tripod rotate 180*z }
        object { tripod rotate 270*z }
        object { tripod rotate 180*x }
        object { tripod rotate 180*x rotate 90*z }
        object { tripod rotate 180*x rotate 180*z }
        object { tripod rotate 180*x rotate 270*z }
        sphere { < 2, 0, 0 >, R }
        sphere { <-2, 0, 0 >, R }
        sphere { < 0, 2, 0 >, R }
        sphere { < 0,-2, 0 >, R }
        sphere { < 0, 0, 2 >, R }
        sphere { < 0, 0,-2 >, R }
        }

File "rhombic_dodecahedron.pov"

#include "colors.inc"
#include "rhombic_dodecahedron.povi"

global_settings{ ambient_light White }
background { color White }

#declare LX = 20;
#declare LZ = 50;
light_source { <LX,-LX,LZ> color White}
light_source { <-LX,LX,LZ> color White}
light_source { <LX,LX,LZ> color White}
light_source { <-LX,-LX,LZ> color White}

object { rhombdod
    texture {
        pigment { colour rgbt <1,1,0.4,0.3> }
        finish { ambient 0.1 diffuse 0.9 phong 1 }
        }
    }


object { rhombdodedges
    texture { pigment { colour Black } }
    }

camera {
    location 15*y
    direction -y
    right 0.3*x
    up 0.3*z
    rotate 10*x
    rotate 30*z
    }

File "rhombic_dodecahedron.ini"

Input_File_Name="rhombic_dodecahedron.pov"
Output_File_Type=N
Library_Path="/sw/share/povray-3.5/include/"
+v

+h256 +w256 Antialias=on